(*
Package for Clifford Algebra in 3-dimensional euclidean and antieuclidean
spaces, including the evaluation of arbitrary functions based on spectral
theory.                       
Author: Josep Manel Parra Serra

Address: Departament de Fisica Fonamental
         Universitat de Barcelona
         Diagonal 647  
         E-08028  Barcelona (Spain)
         e-mail: jmparra@hermes.ffn.ub.es
         FAX: 34 3 402 11 49
*)

<<gibbs.m
Qp::usage= "Qp[q1, ..., qn] evaluates the quaternionic product of n
quaternions. Quaternions are specified in the form {scalar, vector}, where
vector can be left as symbolic or made explicit in the form {v1,v2,v3}."

QFun::usage= "QFun[function, q] evaluates function[q]. Examples are QFun[Cos,q],
QFun[Function[x, 1/x],q]."

C3p::usage= "C3p[cl1, ..., cln] evaluates the product of n elements of the
Clifford algebra of the Euclidean space with signature +++. These elements can
be given either in the scalar-vector notation {scalar, vector, bivector,
pseudoscalar} or in the structured-component form {scalar,{v1,v2,v3},
{bv1,bv2,bv3},psudoescalar}."

C3n::usage= "C3p[cl1, ..., cln] evaluates the product of n elements of the
Clifford algebra of the (anti)Euclidean space of signature ---. These elements
can be given either in the scalar-vector notation {scalar, vector, bivector,
pseudoscalar} or in the structured-component form {scalar,{v1,v2,v3},
{bv1,bv2,bv3},psudoescalar}."

CC3p::usage= "CC3p[cl1,cl2] gives the Clifford commutator in the Cl(3,0)
algebra." 

CC3n::usage= "CC3p[cl1,cl2] gives the Clifford commutator in the Cl(3,0)
algebra." 

SN3p::usage= "SN3p[cl1] gives the so called spinorial norm of an element in
Cl(3,0). It is the result of the product C3p[cl1,GRev3[cl1]]. In three
dimensions it has scalar and pseudoscalar parts, so it is equivalent to a
complex number. It plays a special role in constructing the general inverse.
Often only the scalar part of the product is considered and called spinor norm."

SN3n::usage= "SN3n[cl1] gives the so called spinorial norm of an element in
Cl(0,3). It is the result of the product C3p[cl1,GRev3[cl1]]. Consisting in
this case in a sum of a scalar and a pseudoscalar, it can be considered as a
dual number." 

Det3p::usage= "Det3p[cl1] gives the characteristic determinant of the element.
It is the square root of the characteristic polynomial of the regular
representation of the element. It is used to determine the invertibility of the
element and the compex spectral points of the element in Cl(3,0)."


Det3n::usage= "Det3n[cl1] gives the characteristic determinant of the element.
It is the square root of the characteristic polynomial of the regular
representation of the element. It is used to determine the invertibility of the
element and the compex spectral points of the element in Cl(0,3)."

Inverse3p::usage= "Inverse3p[cl1] gives the inverse in the Cl(3,0) when it
exists." 
Inverse3n::usage= "Inverse3n[cl1] gives the inverse in the Cl(0,3)
when it exists."

GI3::usage= "GI3[cl1] gives the grade (or main) involution of the element.
Changes the sign of the elements of odd degree."

Rev3::usage= "Rev3[cl1] gives the reverse of the element. It is the
antiinvolution that reverses the order in the geometric product of the units."

GRev3::usage= "GRev3[cl1] gives the `grade' reversion of the element. Often
called (Clifford) conjugation, it results of the successive application, in any
order, of the grade involution and the reversion."

Dual3p::usage= "Dual3p[cl1] gives the `dual' of the element in Cl(3,0). It is
the outcome of the product with the unit pseudoscalar and thus is the Clifford
algebraic counterpart of both the original Grassmann's `Erganzung' and Hodge
star operator."

Dual3n::usage= "Dual3n[cl1] gives the `dual' of the element in Cl(0,3). It is
the outcome of the product with the unit pseudoscalar and thus is the Clifford
algebraic counterpart of both the original Grassmann's `Erganzung' and Hodge
star operator."

UTL3p::usage= "UTL3p[a,b] is the universal transformation law  A B /A in Cl(3,0)."
UTL3n::usage= "UTL3n[a,b] is the universal transformation law  A B /A in Cl(0,3)."


Part30::usage= "Part30[cl1] gives the scalar part (geometrical degree 0) of the
element."
Part31::usage= "Part31[cl1] gives the vector part (geometrical degree 1) of the
element."
Part32::usage= "Part32[cl1] gives the bivector part (geometrical degree 2) of the
element."
Part33::usage= "Part33[cl1] gives the pseudoscalar or volumic part (geometrical
degree 3) of the element."

rg3p::usage= "rg3p[{8-list}] gives the regular matrix representation of an
element of Cl(3,0) whose components are expressed in alphabetical ordering
forming a single list of eight elements."
rg3n::usage= "rg3n[{8-list}] gives the regular matrix representation of an
element of Cl(0,3) whose components are expressed in alphabetical ordering
forming a single list of eight elements."
r3p::usage= "rg3p[cl1] gives the regular matrix representation of an
element of Cl(3,0) expressed in the standard geometric form."
r3n::usage= "rg3n[cl1] gives the regular matrix representation of an
element of Cl(0,3) expressed in the standard geometric form."


StoA::usage= "StoA[cl1] gives the eight components of the element as a single
list corresponding to the pure alphabetic ordering of the basis. The ordering
change in the bivector components makes this function different from the simple
Flatten[cl1] provided in Mathematica." 

AtoS::usage= "AtoS[cl1] gives the Structured (in our program adopted as
Standard) form of an element {scalar,{vector},{bivector},pseudoscalar} starting
from the alphabetic ordering of the components."

StoG::usage= "StoG[cl1] gives the geometric expression of an element including
the basis multivectors. It is the expression used in handwriten computations or
used in CLICAL."
StoGG::usage= "StoGG[cl1] gives the geometric expression of an element including
the basis multivectors. This time the indices of the basis multivectors are
placed as arguments, as in more general Mathematica programmes. Its use is
intended to facilitate interchange with other programs."

StoM::usage= "StoM[cl1] gives the Pauli Matrix representation of an element of
Cl(3,0). Paui matrices are named sigma1,sigma2,sigma3 and are identified with
the basis vectors e1,e2,e3; sigma0 is the identity."

MtoS::usage= "MtoS[complex 2x2 matrix] gives the clifford element that
corresponds to an arbitrary element in the Pauli matrix algebra."

StoQ::usage= "StoQ[cl1] gives the ordered pair of quaternions that allow to
express the Clifford algebra Cl(0,3) as a double quaternion structure. See
QCP." 

QtoS::usage= "QtoS[{quat1,quat2}] gives the Clifford element in Cl(0,3) that
correspond to an ordered pair of quaternions. See QCP."

QCP::usage= "QCP[{quat1,quat2},{quat3,quat4}] is the product in the double
quaternion ring that allows the establishment of an isomorphism between this
double algebra and the Clifford algebra Cl(0,3). See StoQ and QtoS."

random3::usage= "random3[] gives a standard three-component random vector with
components in the range (-1,1), to allow plurality of signs."

random8::usage= "random8[] gives a eight-component random vector or array with
values in the (-1,1) range."

random::usage= "random[] gives a random clifford element with components in the (-1,1)
range." 

crandom::usage= "crandom[] gives a random clifford element with complex number
coefficients with rea and imaginary parts in the range (-1,1)."

Nabla3p::usage= "Nabla3p[cl1] gives the outcome of the nabla or
clifford-gradient-derivative operator upon an element of Cl(3,0) that depends
on the cartesian variables x,y,z."
Nabla3n::usage= "Nabla3n[cl1] gives the outcome of the nabla or
clifford-gradient-derivative operator upon an element of Cl(0,3) that depends
on the cartesian variables x,y,z."
ExtD3p::usage= "ExtD3p[cl1] gives the exterior derivative of an element of
Cl(3,0) whose components are functions of the cartesian variables x,y,z. We
notice that the signature-dependence of the exterior derivative is the result
of adopting the contravariant basis vectors as the basis for the geometric
Clifford algebra."
ExtD3n::usage= "ExtD3n[cl1] gives the exterior derivative of an element of
Cl(3,0) whose components are functions of the cartesian variables x,y,z. We
notice that the signature-dependence of the exterior derivative is the result
of adopting the contravariant basis vectors as the basis for the geometric
Clifford algebra."
Codif3::usage= "Codif3[cl1] gives the exterior derivative of an element of
Cl(3,0) or Cl(0,3) whose components are functions of the cartesian variables
x,y,z. We notice that the signature-independence of the codifferential is
the result of adopting the contravariant basis vectors as the basis for the
geometric Clifford algebra."

TpNablap::usage= "TpNablap[cl1] adds a positive scalar time (t) derivative to
the Nabla3p[cl1]. Although useful in three-dimensional presentations of
electromagnetism we encourage the use of the Clifford algebras in four
dimensions Cl(1,3) or Cl(3,1) for these problems."

TnNablap::usage= "TnNablap[cl1] adds a negative scalar time (t) derivative to
the Nabla3p[cl1]. Although useful in three-dimensional presentations of
electromagnetism we encourage the use of the Clifford algebras in four
dimensions Cl(1,3) or Cl(3,1) for these problems."

TpNablan::usage= "TpNablan[cl1] adds a positive scalar time (t) derivative to
the Nabla3n[cl1]. Although useful in three-dimensional presentations of
electromagnetism we encourage the use of the Clifford algebras in four
dimensions Cl(1,3) or Cl(3,1) for these problems."

TnNablan::usage= "TnNablan[cl1] adds a negative scalar time (t) derivative to
the Nabla3n[cl1]. Although useful in three-dimensional presentations of
electromagnetism we encourage the use of the Clifford algebras in four
dimensions Cl(1,3) or Cl(3,1) for these problems."

LapBel3p::usage= "LapBel3p[cl1] gives the Laplace-Beltrami operator action upon
an element of Cl(3,0) whose components are specified as functions of the
Cartesian coordinates x,y,z."
LapBel3n::usage= "LapBel3n[cl1] gives the Laplace-Beltrami operator action upon
an element of Cl(0,3) whose components are specified as functions of the
Cartesian coordinates x,y,z."



CFun1p::usage= "CFun1p[Cos,cl1] or CFun1p[Function[x,x**a],cl1] gives the
Cosinus or the a-power of an element of Cl(3,0). Any function of complex
variable defined in Mathematica is made available upon Cl(3,0). It uses the
standard Re and Im of Mathematica."

CFun2p::usage= "CFun2p[Cos,cl1] or CFun2p[Function[x,x**a],cl1] gives the
Cosinus or the a-power of an element of Cl(3,0). Any function of complex
variable defined in Mathematica is made available upon Cl(3,0). It uses the
RPart and IPart functions defined above, useful when the only
imaginary-dependence is explicitely stated by means of the I."

CFun1n::usage= "CFun1n[Cos,cl1] or CFun1n[Function[x,x**a],cl1] gives the
Cosinus or the a-power of an element of Cl(0,3). Any function of complex
variable defined in Mathematica is made available upon Cl(0,3). It uses the
standard Re and Im of Mathematica."
CFun2n::usage= "CFun2n[Cos,cl1] or CFun2n[Function[x,x**a],cl1] gives the
Cosinus or the a-power of an element of Cl(0,3). Any function of complex
variable defined in Mathematica is made available upon Cl(0,3). It avoids the
use of the standard Re and Im of Mathematica as well as RPart and IPart."

CFun3n::usage= "CFun3n[Cos,cl1] or CFun3n[Function[x,x**a],cl1] gives the
Cosinus or the a-power of an element of Cl(0,3). Any function of complex
variable defined in Mathematica is made available upon Cl(0,3). It uses the
RPart and IPart functions defined above."

CFun4n::usage= "CFun4n[Cos,cl1] or CFun4n[Function[x,x**a],cl1] gives the
Cosinus or the a-power of an element of Cl(0,3). Any function of complex
variable defined in Mathematica is made available upon Cl(3,0). It uses the
quaternionic function QFun[q1] defined above."


(* Complex-value manipulation when the whole imaginary dependence is 
explicitely written in terms of the imaginary unit I. *)

ComplexConjugate[v_] := v /. Complex[x_,y_] -> x - I y 
RPart[v_] := Expand[(v + ComplexConjugate[v])/2]     
IPart[v_] := Expand[(v - ComplexConjugate[v])/(2I)]

(* Quaternionic product and quaternionic functions:  *)

Qp[{x_, y_}, {u_, v_}] := {x*u - y . v, x*v + u*y + Cross[y, v]};
Qp[a_,b__]:= Fold[Qp,a,{b}];
Attributes[Qp]={Flat};

QFun[func_,x_]:= Module[{n1,v1,z1},
n1=Sqrt[x[[2]] . x[[2]]];
v1=x[[2]] / n1;
z1=func[x[[1]]+ I n1];
result= Chop[{Re[z1], Im[z1] v1}]  ]



(* Clifford Product for signature +++,  CliffordAlgebra(3,0),
   isomorphic to Pauli's matrix algebra *)

C3p[{x_, v_, a_, y_},{z_, w_, b_, t_}] :=
{x*z + v . w - a . b - y*t ,
 x*w + v*z - y*b - a*t - Cross[v, b] - Cross[a, w] ,
 x*b + a*z + y*w + v*t + Cross[v, w] - Cross[a, b] ,
 x*t + y*z + v . b + a . w }

C3p[a_,b__]:= Fold[C3p,a,{b}];
Attributes[C3p] = {Flat};
CC3p[a_,b_]:= C3p[a,b]-C3p[b,a];
CA3p[a_,b_]:= C3p[a,b]+C3p[b,a];

(* Clifford product for signature ---,  CliffordAlgebra(0,3), 
    isomorphic to a double quaternion algebra *)

C3n[{x_, v_, a_, y_},{z_, w_, b_, t_}] :=
{x*z - v . w - a . b + y*t ,
 x*w + v*z - y*b - a*t + Cross[v, b] + Cross[a, w] ,
 x*b + a*z - y*w - v*t + Cross[v, w] + Cross[a, b] ,
 x*t + y*z + v . b + a . w }

C3n[a_,b__]:= Fold[C3n,a,{b}];
Attributes[C3n] = {Flat}
CC3n[a_,b_]:= C3n[a,b]-C3n[b,a];
CA3n[a_,b_]:= C3n[a,b]+C3n[b,a];

(* (Generalized) Spinorial Norm for signatures +++  i  ---   *)

SN3p[{x_, v_, a_, y_}] := { x^2 + a . a - y^2 - v . v ,{0,0,0},{0,0,0},
    2*(x*y - v . a)}
    
SN3n[{x_, v_, a_, y_}] := { x^2 + a . a + y^2 + v . v ,{0,0,0},{0,0,0},
    2*(x*y - v . a)}    
    
(* Characteristic Determinant for signatures +++  i  ---  *)

Det3p[{x_, v_, a_, y_}] := (x^2 + a . a - y^2 - v . v)^2 + 4*(x*y - v . a)^2
    
Det3n[{x_, v_, a_, y_}] := (x^2 + a . a + y^2 + v . v)^2 - 4*(x*y - v . a)^2

(* Inverses for signatures +++  i  --- *)

Inverse3p[{x_, v_, a_, y_}] := C3p[{ x^2 + a . a - y^2 - v . v ,{0,0,0},{0,0,0},
   - 2*(x*y - v . a)},{x, -v, -a, y}] / Det3p[{x, v, a, y}]
    
Inverse3n[{x_, v_, a_, y_}] := C3n[{ x^2 + a . a + y^2 + v . v ,{0,0,0},{0,0,0},
    - 2*(x*y - v . a)},{x, -v, -a, y}]  / Det3n[{x, v, a, y}]    

(* Universal Transformation Law for signatures +++  and --- , the operador is
the factor at left and the first argument of the function: *)    

UTL3p[a_, b_] := C3p[a,b,Inverse3p[a]]
UTL3n[a_, b_] := C3n[a,b,Inverse3n[a]]

(* Main or Grade Involution, Reversion, and Graded reversion or (Clifford
conjugation), and duals (times the unit volume) *)
  
GI3[{x_, v_, a_, y_}] := {x, - v, a, -y};
Rev3[{x_, v_, a_, y_}] := {x, v, - a, -y};
GRev3[x_]:= GI3[Rev3[x]];
Dual3p[{x_, v_, a_, y_}] := {-y, -a, v, x};
Dual3n[{x_, v_, a_, y_}] := {y, -a, -v, x};    

(*  Projectors upon the several exterior degrees *)

Part30[{x_, v_, a_, y_}] := x
Part31[{x_, v_, a_, y_}] := v
Part32[{x_, v_, a_, y_}] := a
Part33[{x_, v_, a_, y_}] := y


(* Regular matrix representations for Cl(3,0) and Cl(0,3)
   rg3p(n)[{flat, alphabetically ordered Clifford element}] *)

rg3p[{a1_, a2_, a3_, a4_, a5_, a6_, a7_, a8_}]:=
  {{a1, a2, a3, a4, -a5, -a6, -a7, -a8}, 
   {a2, a1, a5, a6, -a3, -a4, -a8, -a7}, 
   {a3, -a5, a1, a7, a2, a8, -a4, a6}, 
   {a4, -a6, -a7, a1, -a8, a2, a3, -a5}, 
   {a5, -a3, a2, a8, a1, a7, -a6, a4}, 
   {a6, -a4, -a8, a2, -a7, a1, a5, -a3}, 
   {a7, a8, -a4, a3, a6, -a5, a1, a2}, 
   {a8, a7, -a6, a5, a4, -a3, a2, a1}}

rg3n[{a1_, a2_, a3_, a4_, a5_, a6_, a7_, a8_}]:=
  {{a1, -a2, -a3, -a4, -a5, -a6, -a7, a8}, 
   {a2, a1, -a5, -a6, a3, a4, -a8, -a7}, 
   {a3, a5, a1, -a7, -a2, a8, a4, a6}, 
   {a4, a6, a7, a1, -a8, -a2, -a3, -a5}, 
   {a5, -a3, a2, -a8, a1, -a7, a6, -a4}, 
   {a6, -a4, a8, a2, a7, a1, -a5, a3}, 
   {a7, -a8, -a4, a3, -a6, a5, a1, -a2}, 
   {a8, a7, -a6, a5, a4, -a3, a2, a1}}

(* regular matrix representations for 3-dimensional Clifford algebras 
   r3p(n)[{structured cliffor}]; matrix indices are always in alphabetic order *)

r3p[{sc_,{a1_,a2_,a3_},{b1_,b2_,b3_},psc_}]:=
  {{sc, a1, a2, a3, -b1, -b2, -b3, -psc}, 
   {a1, sc, b3, -b2, -psc, a3, -a2, -b1}, 
   {a2, -b3, sc, b1, -a3, -psc, a1, -b2}, 
   {a3, b2, -b1, sc, a2, -a1, -psc, -b3}, 
   {b1, psc, -a3, a2, sc, b3, -b2, a1},    
   {b2, a3, psc, -a1, -b3, sc, b1, a2}, 
   {b3, -a2, a1, psc, b2, -b1, sc, a3}, 
   {psc, b1, b2, b3, a1, a2, a3, sc}}

r3n[{sc_,{a1_,a2_,a3_},{b1_,b2_,b3_},psc_}]:=
  {{sc, -a1, -a2, -a3, -b1, -b2, -b3, psc}, 
   {a1, sc, -b3, b2, -psc, -a3, a2, -b1}, 
   {a2, b3, sc, -b1, a3, -psc, -a1, -b2}, 
   {a3, -b2, b1, sc, -a2, a1, -psc, -b3}, 
   {b1, -psc, -a3, a2, sc, -b3, b2, -a1}, 
   {b2, a3, -psc, -a1, b3, sc, -b1, -a2}, 
   {b3, -a2, a1, -psc, -b2, b1, sc, -a3},    
   {psc, b1, b2, b3, a1, a2, a3, sc}}


 
(* Combining different expressions: Alphabetic, Sructured or Standard,
Geometric and Matrix forms for the elements in the algebra *) 

StoA[{alpha_,{v1_,v2_,v3_},{bv1_,bv2_,bv3_},lambda_}]:=
{alpha,v1,v2,v3,bv3,-bv2,bv1,lambda};
AtoS[{alpha_,v1_,v2_,v3_,bv3_,bv2_,bv1_,lambda_}]:=
{alpha,{v1,v2,v3},{bv1,-bv2,bv3},lambda};

StoG[{alpha_,{v1_,v2_,v3_},{bv1_,bv2_,bv3_},lambda_}]:=
alpha + v1 e1+ v2 e2+ v3 e3+ bv1 e23 + bv2 e31 + bv3 e12+ lambda e123;

StoGG[{alpha_,{v1_,v2_,v3_},{bv1_,bv2_,bv3_},lambda_}]:=
alpha e[]+ v1 e[1]+ v2 e[2]+ v3 e[3]+ bv1 e[2,3] + bv2 e[3,1] + bv3 e[1,2]+
 lambda e[1,2,3];

(* matrius de Pauli per a C3p *)
sigma1:={{0,1},{1,0}};
sigma2:={{0,-I},{I,0}};
sigma3:={{1,0},{0,-1}};
sigma0:={{1,0},{0,1}};

StoM[{alpha_,{v1_,v2_,v3_},{bv1_,bv2_,bv3_},lambda_}]:=
     alpha*sigma0+v1*sigma1+v2*sigma2+ v3*sigma3 + I*bv1*sigma1 + 
     I*bv2*sigma2+ I*bv3*sigma3+I*lambda*sigma0;

MtoS[a__]:=Chop[(1/2)*{RPart[a[[1,1]]+a[[2,2]]],{RPart[a[[1,2]]+a[[2,1]]],
                  IPart[a[[2,1]]-a[[1,2]]],RPart[a[[1,1]]-a[[2,2]]]},
                  {IPart[a[[1,2]]+a[[2,1]]],RPart[a[[1,2]]-a[[2,1]]],
                  IPart[a[[1,1]]-a[[2,2]]]},IPart[a[[1,1]]+a[[2,2]]]}]
StoQ[{x_, v_, a_, y_}]:= {{x+y, a-v},{x-y, a+v}};
QtoS[{{a_,b_},{c_,d_}}]:=(1/2)*{a+c,d-b,b+d,a-c};

QCP[{a_,b_},{c_,d_}]:={Qp[a,c], Qp[b,d]};
QCP[a_,b__]:= Fold[QCP,a,{b}];
Attributes[QCP]={Flat};

(* Some useful elements *)

ee={1,{0,0,0},{0,0,0},0}
ee1={0,{1,0,0},{0,0,0},0}
ee2={0,{0,1,0},{0,0,0},0}
ee3={0,{0,0,1},{0,0,0},0}
ee23={0,{0,0,0},{1,0,0},0}
ee31={0,{0,0,0},{0,1,0},0}
ee12={0,{0,0,0},{0,0,1},0}
ee123={0,{0,0,0},{0,0,0},1}

random3[]:= Table[Random[Real,{-1,1}],{i,1,3}]
random8[]:= Table[Random[Real,{-1,1}],{i,1,8}]
random[]:= AtoS[random8[]]
crandom[]:= random[]+ I random[]
randomq[]:= {Random[Real,{-1,1}],random3[]}
elemor={1,{2,3,4},{5,6,7},8};
elemv={alpha,{v1,v2,v3},{bv1,bv2,bv3},lambda};
elemw={beta,{w1,w2,w3},{bw1,bw2,bw3},mu};
qfield={s[x,y,z],{a1[x,y,z],a2[x,y,z],a3[x,y,z]}};
field={s[x,y,z],{a1[x,y,z],a2[x,y,z],a3[x,y,z]},
                {b1[x,y,z],b2[x,y,z],b3[x,y,z]}, ps[x,y,z]};
tdfield={st[t,x,y,z],{at1[t,x,y,z],at2[t,x,y,z],at3[t,x,y,z]},
                {bt1[t,x,y,z],bt2[t,x,y,z],bt3[t,x,y,z]}, pst[t,x,y,z]};

z3={0,0,0};
z4={0,z3};



(* Nabla and associated operators  *)

Nabla3p[{x_, v_, a_, y_}] := { Div[v], Grad[x]- Curl[a], Curl[v] + Grad[y], 
                              Div[a]}
Nabla3n[{x_, v_, a_, y_}] := { Div[v], -Grad[x]- Curl[a], -Curl[v] + Grad[y], 
                              - Div[a]}


ExtD3p[{x_, v_, a_, y_}] := { 0, Grad[x], Curl[v] , Div[a]}
ExtD3n[{x_, v_, a_, y_}] := { 0, -Grad[x], -Curl[v] , -Div[a]}

Codif3[{x_, v_, a_, y_}] := { Div[v], - Curl[a],  Grad[y], 0} 

TpNablap[a__]:= D[a,t]+Nabla3p[a];
TnNablap[a__]:= -D[a,t]+Nabla3p[a];
TpNablan[a__]:= D[a,t]+Nabla3n[a];
TnNablan[a__]:= -D[a,t]+Nabla3n[a];

LapBel3p[x_]:= Nabla3p[Nabla3p[x]]
LapBel3n[x_]:= Nabla3n[Nabla3n[x]]                              

(* Spectral block for Cl(3,0) *)

CFun1p[ func_,{x_, v_, a_, y_}] :=
Module[ {aux1, aux2, aux3, aux4, xx1, yy1, xx2, yy2, rr1, rr2, ss},
aux1= v . v - a . a + 2*I*(v . a); aux2= Sqrt[aux1] ; 
rr1 =Re[aux2]  ; rr2 = Im[aux2] ; ss = rr1^2+rr2^2 ;
aux3 = func[x+ I*y + aux2] ; aux4 = func[x+ I*y - aux2] ;
xx1 = Re[aux3] ; xx2 = Re[aux4]; yy1 = Im[aux3]; yy2 = Im[aux4];
result = {(xx1+xx2)/2, 
(rr1*(xx1-xx2)+rr2*(yy1-yy2))*(1/(2*ss))*v -
(rr1*(yy1-yy2)-rr2*(xx1-xx2))*(1/(2*ss))*a,
(rr1*(xx1-xx2)+rr2*(yy1-yy2))*(1/(2*ss))*a +
(rr1*(yy1-yy2)-rr2*(xx1-xx2))*(1/(2*ss))*v,
(yy1+yy2)/2}  ]


CFun2p[ func_,{x_, v_, a_, y_}] :=
Module[ {aux1, aux2, aux3, aux4, xx1, yy1, xx2, yy2, rr1, rr2, ss},
aux1= v . v - a . a + 2*I*(v . a); aux2= Sqrt[aux1] ; 
rr1 =RPart[aux2]  ; rr2 = IPart[aux2] ; ss = rr1^2+rr2^2 ;
aux3 = func[x+ I*y + aux2] ; aux4 = func[x+ I*y - aux2] ;
xx1 = RPart[aux3] ; xx2 = RPart[aux4]; yy1 = IPart[aux3]; yy2 = IPart[aux4];
Result = Chop[{(xx1+xx2)/2, 
(rr1*(xx1-xx2)+rr2*(yy1-yy2))*(1/(2*ss))*v -
(rr1*(yy1-yy2)-rr2*(xx1-xx2))*(1/(2*ss))*a,
(rr1*(xx1-xx2)+rr2*(yy1-yy2))*(1/(2*ss))*a +
(rr1*(yy1-yy2)-rr2*(xx1-xx2))*(1/(2*ss))*v,
(yy1+yy2)/2}]
] 


CFun1n[func_,x_]:= Module[{y,n1,n2,v1,v2,z1,z2},
y=StoQ[x]; 
n1=Sqrt[y[[1,2]] . y[[1,2]]];
n2=Sqrt[y[[2,2]] . y[[2,2]]];
v1=y[[1,2]] / n1;
v2=y[[2,2]] / n2;
z1=func[y[[1,1]]+ I n1];
z2=func[y[[2,1]]+ I n2];
result= Chop[{(Re[z1]+Re[z2])/2, (Im[z2] v2 - Im[z1] v1)/2,
           (Im[z2] v2 + Im[z1] v1)/2,(Re[z1]-Re[z2])/2}] ]

CFun2n[func_,x_]:= Module[{y,n1,n2,v1,v2,z1,z2,zc1,zc2},
y=StoQ[x]; 
n1=Sqrt[y[[1,2]] . y[[1,2]]];
n2=Sqrt[y[[2,2]] . y[[2,2]]];
v1=y[[1,2]] / n1;
v2=y[[2,2]] / n2;
z1=func[y[[1,1]]+ I n1];
z2=func[y[[2,1]]+ I n2];
zc1=func[y[[1,1]]- I n1];
zc2=func[y[[2,1]]- I n2];
result= Chop[{(z1+z2+zc1+zc2)/4, I (zc2-z2)/4 v2 +I (z1- zc1)/4 v1,
           I (zc2-z2)/4 v2 + I (zc1-z1)/4 v1,(z1+zc1-z2-zc2)/4}] ]

CFun3n[func_,x_]:= Module[{y,n1,n2,v1,v2,z1,z2},
y=StoQ[x]; 
n1=Sqrt[y[[1,2]] . y[[1,2]]];
n2=Sqrt[y[[2,2]] . y[[2,2]]];
v1=y[[1,2]] / n1;
v2=y[[2,2]] / n2;
z1=func[y[[1,1]]+ I n1];
z2=func[y[[2,1]]+ I n2];
result= Chop[{(RPart[z1]+RPart[z2])/2, (IPart[z2] v2 - IPart[z1] v1)/2,
           (IPart[z2] v2 + IPart[z1] v1)/2,(RPart[z1]-RPart[z2])/2}] ]

CFun4n[func_,x_]:= Module[{q,q1,q2,q3},
q=StoQ[x]; q1=q[[1]]; q2=q[[2]];
q3={QFun[func,q1],QFun[func,q2]};
result=QtoS[q3] ]
 
(*  End of the package for 3 dimensions  *)
(*  Complementary files: rotations and conformal transformations;
                         maxwell equations and the Lorentz group *)